a49a58bc45
This reverts commit 8312713dc2.
See nix#9428. Path coercion like `"${./.}"` in flakes causes the path to
be copied to the store twice; using the `self` argument works around
this. However, as `lib.fileset` doesn't support using `self`, so we need
to go back to `nix-filter`
Signed-off-by: seth <getchoo@tuta.io>
123 lines
3.1 KiB
Nix
123 lines
3.1 KiB
Nix
{
|
|
description = "A custom launcher for Minecraft that allows you to easily manage multiple installations of Minecraft at once (Fork of MultiMC)";
|
|
|
|
nixConfig = {
|
|
extra-substituters = [ "https://cache.garnix.io" ];
|
|
extra-trusted-public-keys = [ "cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g=" ];
|
|
};
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
|
|
|
|
libnbtplusplus = {
|
|
url = "github:PrismLauncher/libnbtplusplus";
|
|
flake = false;
|
|
};
|
|
|
|
nix-filter.url = "github:numtide/nix-filter";
|
|
|
|
/*
|
|
Inputs below this are optional and can be removed
|
|
|
|
```
|
|
{
|
|
inputs.prismlauncher = {
|
|
url = "github:PrismLauncher/PrismLauncher";
|
|
inputs = {
|
|
flake-compat.follows = "";
|
|
};
|
|
};
|
|
}
|
|
```
|
|
*/
|
|
|
|
flake-compat = {
|
|
url = "github:edolstra/flake-compat";
|
|
flake = false;
|
|
};
|
|
};
|
|
|
|
outputs =
|
|
{
|
|
self,
|
|
nixpkgs,
|
|
libnbtplusplus,
|
|
nix-filter,
|
|
...
|
|
}:
|
|
let
|
|
inherit (nixpkgs) lib;
|
|
|
|
# While we only officially support aarch and x86_64 on Linux and MacOS,
|
|
# we expose a reasonable amount of other systems for users who want to
|
|
# build for most exotic platforms
|
|
systems = lib.systems.flakeExposed;
|
|
|
|
forAllSystems = lib.genAttrs systems;
|
|
nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
|
|
in
|
|
{
|
|
checks = forAllSystems (
|
|
system:
|
|
let
|
|
checks' = nixpkgsFor.${system}.callPackage ./nix/checks.nix { inherit self; };
|
|
in
|
|
lib.filterAttrs (_: lib.isDerivation) checks'
|
|
);
|
|
|
|
devShells = forAllSystems (
|
|
system:
|
|
let
|
|
pkgs = nixpkgsFor.${system};
|
|
in
|
|
{
|
|
default = pkgs.mkShell {
|
|
inputsFrom = [ self.packages.${system}.prismlauncher-unwrapped ];
|
|
buildInputs = with pkgs; [
|
|
ccache
|
|
ninja
|
|
];
|
|
};
|
|
}
|
|
);
|
|
|
|
formatter = forAllSystems (system: nixpkgsFor.${system}.nixfmt-rfc-style);
|
|
|
|
overlays.default =
|
|
final: prev:
|
|
let
|
|
version = builtins.substring 0 8 self.lastModifiedDate or "dirty";
|
|
in
|
|
{
|
|
prismlauncher-unwrapped = prev.callPackage ./nix/unwrapped.nix {
|
|
inherit
|
|
libnbtplusplus
|
|
nix-filter
|
|
self
|
|
version
|
|
;
|
|
};
|
|
|
|
prismlauncher = final.callPackage ./nix/wrapper.nix { };
|
|
};
|
|
|
|
packages = forAllSystems (
|
|
system:
|
|
let
|
|
pkgs = nixpkgsFor.${system};
|
|
|
|
# Build a scope from our overlay
|
|
prismPackages = lib.makeScope pkgs.newScope (final: self.overlays.default final pkgs);
|
|
|
|
# Grab our packages from it and set the default
|
|
packages = {
|
|
inherit (prismPackages) prismlauncher-unwrapped prismlauncher;
|
|
default = prismPackages.prismlauncher;
|
|
};
|
|
in
|
|
# Only output them if they're available on the current system
|
|
lib.filterAttrs (_: lib.meta.availableOn pkgs.stdenv.hostPlatform) packages
|
|
);
|
|
};
|
|
}
|